/*
 * Licensed to the Apache Software Foundation (ASF) under one or more
 * contributor license agreements.  See the NOTICE file distributed with
 * this work for additional information regarding copyright ownership.
 * The ASF licenses this file to You under the Apache License, Version 2.0
 * (the "License"); you may not use this file except in compliance with
 * the License.  You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

// Set up cross-project dependency on test classes. This should be resolved by pulling reused classes into
// a separate regular module. Exporting test classes is sort of weird.
configure([project(":lucene:spatial3d"),
           project(":lucene:analysis:common"),
           project(":lucene:backward-codecs"),
           project(":lucene:queryparser"),
           project(":solr:contrib:dataimporthandler")]) {
  plugins.withType(JavaPlugin) {
    configurations {
      testClassesExported
    }

    artifacts {
      testClassesExported sourceSets.test.java.outputDir, {
        builtBy testClasses
      }
    }
  }
}

configure(project(":lucene:spatial-extras")) {
  plugins.withType(JavaPlugin) {
    dependencies {
      testImplementation project(path: ':lucene:spatial3d', configuration: 'testClassesExported')
    }
  }
}

configure(project(":solr:core")) {
  plugins.withType(JavaPlugin) {
    dependencies {
      testImplementation project(path: ':lucene:backward-codecs', configuration: 'testClassesExported')
      testImplementation project(path: ':lucene:queryparser', configuration: 'testClassesExported')
    }
  }
}

configure(project(":solr:contrib:analysis-extras")) {
  plugins.withType(JavaPlugin) {
    dependencies {
      testImplementation project(path: ':lucene:analysis:common', configuration: 'testClassesExported')
      testImplementation project(path: ':solr:contrib:dataimporthandler', configuration: 'testClassesExported')
    }
  }
}

configure(project(":solr:contrib:dataimporthandler-extras")) {
  plugins.withType(JavaPlugin) {
    dependencies {
      testImplementation project(path: ':solr:contrib:dataimporthandler', configuration: 'testClassesExported')
    }
  }
}