/*
 * Licensed to the Apache Software Foundation (ASF) under one or more
 * contributor license agreements.  See the NOTICE file distributed with
 * this work for additional information regarding copyright ownership.
 * The ASF licenses this file to You under the Apache License, Version 2.0
 * (the "License"); you may not use this file except in compliance with
 * the License.  You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

// Adapt to custom, legacy folder convention.
allprojects {
  plugins.withType(JavaPlugin) {
    sourceSets {
      main.java.srcDirs = ['src/java']
      main.resources.srcDirs = ['src/resources']
      test.java.srcDirs = ['src/test']
      test.resources.srcDirs = ['src/test-files']
    }

    tasks.named('processTestResources').configure {
      from('src/test') {
        exclude '**/*.java'
      }
    }

    // if 'src/tools' exists, add it as a separate sourceSet.
    if (file('src/tools/java').exists()) {
      sourceSets {
        tools {
          java {
            srcDirs = ['src/tools/java']
          }
        }
      }

      configurations {
        // Inherit any dependencies from the main source set.
        toolsImplementation.extendsFrom implementation
      }
    }
  }
}