/*
 * Licensed to the Apache Software Foundation (ASF) under one or more
 * contributor license agreements.  See the NOTICE file distributed with
 * this work for additional information regarding copyright ownership.
 * The ASF licenses this file to You under the Apache License, Version 2.0
 * (the "License"); you may not use this file except in compliance with
 * the License.  You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */


// I am not convinced packaging of examples should be a separate project... Seems more logical to
// move it to just the packaging project (?). Let's leave it for now though.

configurations {
  packaging
  postJar
  dih
}

dependencies {
  postJar project(path: ":solr:core", configuration: "postJar")
  dih 'org.hsqldb:hsqldb'
  dih 'org.apache.derby:derby'
}

ext {
  packagingDir = file("${buildDir}/packaging")
}

task assemblePackaging(type: Sync) {
  from(projectDir, {
    include "example-DIH/**"
    include "exampledocs/**"
    include "files/**"
    include "films/**"
    include "README.md"
    exclude "**/*.jar"
  })

  from(configurations.postJar, {
    into "exampledocs/"
  })

  from(configurations.dih, {
    into "example-DIH/solr/db/lib"
  })

  into packagingDir
}

artifacts {
  packaging packagingDir, {
    builtBy assemblePackaging
  }
}