spring-security/build.gradle

buildscript {
	dependencies {
		classpath 'io.spring.gradle:spring-build-conventions:0.0.15.RELEASE'
		classpath "org.springframework.boot:spring-boot-gradle-plugin:$springBootVersion"
	}
	repositories {
		maven { url 'https://repo.spring.io/plugins-snapshot' }
	}
}
apply plugin: 'io.spring.convention.root'

group = 'org.springframework.security'
description = 'Spring Security'

ext.snapshotBuild = version.contains("SNAPSHOT")
ext.releaseBuild = version.contains("SNAPSHOT")
ext.milestoneBuild = !(snapshotBuild || releaseBuild)

dependencyManagementExport.projects = subprojects.findAll { !it.name.contains('-boot') }

// Disable JaCoCo when not explicitly requested to enable caching of test
// See https://discuss.gradle.org/t/do-not-cache-if-condition-matched-jacoco-agent-configured-with-append-true-satisfied/23504
gradle.taskGraph.whenReady { graph ->
	def enabled = graph.allTasks.any { it instanceof JacocoReport }
	subprojects { project ->
		project.plugins.withType(JacocoPlugin) {
		    project.tasks.withType(Test) {
		        jacoco.enabled = enabled
		    }
		}
	}
}