hibernate-orm/gradle/publishing-repos.gradle

/*
 * Hibernate, Relational Persistence for Idiomatic Java
 *
 * License: GNU Lesser General Public License (LGPL), version 2.1 or later
 * See the lgpl.txt file in the root directory or http://www.gnu.org/licenses/lgpl-2.1.html
 */

apply from: rootProject.file( 'gradle/base-information.gradle' )


apply plugin: 'maven-publish'
apply plugin: 'org.hibernate.build.maven-repo-auth'
apply plugin: 'com.jfrog.bintray'


ext {
	bintrayUser = project.hasProperty( 'PERSONAL_BINTRAY_USER' ) ? project.property( 'PERSONAL_BINTRAY_USER' ) : null
	bintrayKey = project.hasProperty( 'PERSONAL_BINTRAY_API_KEY' ) ? project.property( 'PERSONAL_BINTRAY_API_KEY' ) : null
}


publishing {
	publications {
		publishedArtifacts( MavenPublication )
	}

	repositories {
		maven {
			name 'jboss-snapshots-repository'
			url 'https://repository.jboss.org/nexus/content/repositories/snapshots'
		}
	}
}

bintray {
	user = project.bintrayUser
	key = project.bintrayKey

	publications = ['publishedArtifacts','relocationArtifacts']

	pkg {
		userOrg = 'hibernate'
		repo = 'artifacts'
		name = 'hibernate-orm'

		publish = true

		version {
			name = project.version
			description ="Hibernate ORM ${project.version} release.  See http://hibernate.org/orm/releases/${project.ormVersion.family}"
			released  = new Date()
			vcsTag = project.version
			gpg {
				sign = true
			}
			attributes = [
					'jpa': project.jpaVersion.name,
					'family': project.ormVersion.family
			]
			mavenCentralSync {
				sync = true
			}
		}
	}
}

model {
	tasks.generatePomFileForPublishedArtifactsPublication {
		destination = file( "${buildDir}/generated-pom.xml" )
	}
}

task generatePomFile( dependsOn: 'generatePomFileForPublishedArtifactsPublication' )