hibernate-orm/build.gradle

/*
 * Hibernate, Relational Persistence for Idiomatic Java
 *
 * License: GNU Lesser General Public License (LGPL), version 2.1 or later.
 * See the lgpl.txt file in the root directory or <http://www.gnu.org/licenses/lgpl-2.1.html>.
 */

buildscript {
	repositories {
		jcenter()
		mavenCentral()
	}
	dependencies {
		classpath 'org.hibernate.build.gradle:hibernate-matrix-testing:3.0.0.Final'
		classpath 'org.hibernate.build.gradle:version-injection-plugin:1.0.0'
		classpath 'gradle.plugin.com.github.lburgazzoli:gradle-karaf-plugin:0.5.1'
		classpath 'org.asciidoctor:asciidoctor-gradle-plugin:1.5.7'
		classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4'
		classpath 'de.thetaphi:forbiddenapis:3.0.1'
		classpath 'org.junit.platform:junit-platform-gradle-plugin:1.0.1'
	}
}

plugins {
	id 'me.champeau.buildscan-recipes' version '0.2.3'
	id 'org.hibernate.build.xjc' version '2.0.1' apply false
	id 'org.hibernate.build.maven-repo-auth' version '3.0.2' apply false
	id 'org.jetbrains.gradle.plugin.idea-ext' version '0.5'
	id 'biz.aQute.bnd' version '5.1.1' apply false
}

allprojects {
	repositories {
		mavenCentral()
		//Allow loading additional dependencies from a local path;
		//useful to load JDBC drivers which can not be distributed in public.
		if (System.env['ADDITIONAL_REPO'] != null) {
			flatDir {
				dirs "${System.env.ADDITIONAL_REPO}"
			}
		}
		// Needed atm for asciidoclet PR-91, which does not seem to work anyway :(
		// todo (6.0) : remove once/if PR-91 ever works and becomes part of asciidoclet proper
		maven {
			name 'jboss-snapshots-repository'
			url 'https://repository.jboss.org/nexus/content/repositories/snapshots'
		}
	}
	apply plugin: 'idea'
	apply plugin: 'eclipse'

	// minimize changes, at least for now (gradle uses 'build' by default)..
	buildDir = "target"

	apply from: rootProject.file( 'gradle/base-information.gradle' )

}


// ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
// Release Task

task release {
	description = "The task performed when we are performing a release build.  Relies on " +
			"the fact that subprojects will appropriately define a release task " +
			"themselves if they have any release-related activities to perform"

	// Force to release with JDK 8. It used to not work on JDK11 because of the hibernate-orm-modules module,
	// but this limitation might be resolved now that this module has been deleted?
	doFirst {
		if ( !JavaVersion.current().isJava8() || !gradle.ext.testedJavaVersionAsEnum.isJava8() ) {
			throw new IllegalStateException( "Please use JDK 8 to perform the release." )
		}
	}
}

task publish {
	description = "The task performed when we want to just publish maven artifacts.  Relies on " +
			"the fact that subprojects will appropriately define a release task " +
			"themselves if they have any release-related activities to perform"
}



// ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
// CI Build Task

task ciBuild {
	description = "The task performed when one of the 'main' jobs are triggered on the " +
			"CI server.  Just as above, relies on the fact that subprojects will " +
			"appropriately define a release task themselves if they have any tasks " +
			"which should be performed from these CI jobs"
}


wrapper {
	// To upgrade the version of gradle used in the wrapper, run:
	//     ./gradlew wrapper --gradle-version NEW_VERSION
	distributionType = Wrapper.DistributionType.ALL
}


buildScan {
	termsOfServiceUrl = 'https://gradle.com/terms-of-service'
	termsOfServiceAgree = 'yes'
}

buildScanRecipes {
	recipe 'git-commit', baseUrl: 'https://github.com/hibernate/hibernate-orm/tree'
}

idea {
//    project {
//		jdkName = baselineJavaVersion
//		languageLevel = baselineJavaVersion
//
//		vcs = 'Git'
//
//		settings {
//			taskTriggers {
//				afterSync tasks.getByName("projects"), tasks.getByName("tasks")
//			}
//		}
//    }
	module {
		name = "hibernate-orm"
	}
}