hibernate-orm/hibernate-integrationtest-java-modules/hibernate-integrationtest-java-modules.gradle

/*
 * Hibernate, Relational Persistence for Idiomatic Java
 *
 * License: GNU Lesser General Public License (LGPL), version 2.1 or later.
 * See the lgpl.txt file in the root directory or <http://www.gnu.org/licenses/lgpl-2.1.html>.
 */

description = 'Integration tests for running Hibernate ORM in the Java module path'

buildscript {
	repositories {
		maven {
			url "https://plugins.gradle.org/m2/"
		}
	}
	dependencies {
		classpath "org.javamodularity:moduleplugin:1.5.0"
	}
}

apply from: rootProject.file( 'gradle/java-module.gradle' )

// No first-class, built-in support for Java modules in Gradle yet,
// so we have to use https://github.com/java9-modularity/gradle-modules-plugin
apply plugin: "org.javamodularity.moduleplugin"

// Override -source and -target to the version being tested (11+, since this module is enabled)
ext.baselineJavaVersion = gradle.ext.testedJavaVersion
tasks.withType( JavaCompile ) {
	sourceCompatibility = project.baselineJavaVersion
	targetCompatibility = project.baselineJavaVersion
}

// Checkstyle fails for module-info
checkstyleMain.exclude '**/module-info.java'

dependencies {
	compile( project( ':hibernate-core' ) )
	compile( project( ':hibernate-envers' ) )
	compile( libraries.jpa )
}

test {
	useJUnit()
}