OpenSearch/plugins/ingest/build.gradle

/*
 * Licensed to Elasticsearch under one or more contributor
 * license agreements. See the NOTICE file distributed with
 * this work for additional information regarding copyright
 * ownership. Elasticsearch licenses this file to you under
 * the Apache License, Version 2.0 (the "License"); you may
 * not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

esplugin {
  description 'Plugin that allows to configure pipelines to preprocess documents before indexing'
  classname 'org.elasticsearch.plugin.ingest.IngestPlugin'
}

dependencies {
  compile 'org.jruby.joni:joni:2.1.6'
  compile (group: 'com.maxmind.geoip2', name: 'geoip2', version: '2.3.1') {
    // we don't use Maxmind's http service:
    exclude group: 'com.google.http-client', module: 'google-http-client'
  }
  testCompile 'org.elasticsearch:geolite2-databases:20151029'
  testCompile 'org.elasticsearch:securemock:1.1'
}

sourceSets {
  test {
    resources {
      srcDir "src/main/packaging/config"
    }
  }
}

task copyDefaultGeoIp2DatabaseFiles(type: Copy) {
  from zipTree(configurations.testCompile.files.find { it.name.contains('geolite2-databases')})
  into "${project.buildDir}/geoip"
  include "*.mmdb"
}

project.bundlePlugin.dependsOn(copyDefaultGeoIp2DatabaseFiles)

compileJava.options.compilerArgs << "-Xlint:-rawtypes,-unchecked"
compileTestJava.options.compilerArgs << "-Xlint:-rawtypes,-unchecked"

bundlePlugin {
  from("${project.buildDir}/geoip") {
    into 'config/geoip'
  }
}