OpenSearch/qa/security-migrate-tests/build.gradle

apply plugin: 'elasticsearch.rest-test'

dependencies {
  testCompile project(path: ':x-plugins:elasticsearch', configuration: 'runtime')
  testCompile project(path: ':x-plugins:elasticsearch-transport-client', configuration: 'runtime')
}

integTest {
  cluster {
    setting 'script.inline', 'true'
    plugin ':x-plugins:elasticsearch'
    extraConfigFile 'x-pack/roles.yml', 'roles.yml'
    [
      test_admin: 'superuser',
      transport_user: 'superuser',
      existing: 'superuser',
      bob: 'actual_role'
    ].each { String user, String role ->
      setupCommand 'setupUser#' + user,
                   'bin/x-pack/users', 'useradd', user, '-p', 'changeme', '-r', role
    }
    waitCondition = { node, ant ->
      File tmpFile = new File(node.cwd, 'wait.success')
      ant.get(src: "http://${node.httpUri()}",
              dest: tmpFile.toString(),
              username: 'test_admin',
              password: 'changeme',
              ignoreerrors: true,
              retries: 10)
      return tmpFile.exists()
    }
  }
}