OpenSearch/qa/full-cluster-restart/build.gradle

/*
 * Licensed to Elasticsearch under one or more contributor
 * license agreements. See the NOTICE file distributed with
 * this work for additional information regarding copyright
 * ownership. Elasticsearch licenses this file to you under
 * the Apache License, Version 2.0 (the "License"); you may
 * not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */


import org.elasticsearch.gradle.Version
import org.elasticsearch.gradle.testclusters.RestTestRunnerTask
import org.elasticsearch.gradle.testclusters.TestDistribution

apply plugin: 'elasticsearch.standalone-test'
apply plugin: 'elasticsearch.testclusters'

// This is a top level task which we will add dependencies to below.
// It is a single task that can be used to backcompat tests against all versions.
task bwcTest {
  description = 'Runs backwards compatibility tests.'
  group = 'verification'
}

for (Version bwcVersion : bwcVersions.indexCompatible) {
  String baseName = "v${bwcVersion}"

  testClusters {
    String configuredTestDistribution = System.getProperty('tests.distribution', 'oss').toUpperCase()
    "${baseName}" {
      testDistribution = configuredTestDistribution
      versions = [ bwcVersion.toString(), project.version ]
      numberOfNodes = 2
      // some tests rely on the translog not being flushed
      setting 'indices.memory.shard_inactive_time', '20m'
      setting 'http.content_type.required', 'true'
      setting 'path.repo', "${buildDir}/cluster/shared/repo/${baseName}"
      if (configuredTestDistribution.equals("DEFAULT")) {
        setting "xpack.security.enabled", "false"
      }
      javaHome = project.file(project.ext.runtimeJavaHome)
    }
  }

  tasks.register("${baseName}#oldClusterTest", RestTestRunnerTask) {
    useCluster testClusters."${baseName}"
    mustRunAfter(precommit)
    doFirst {
      project.delete("${buildDir}/cluster/shared/repo/${baseName}")
    }

    systemProperty 'tests.is_old_cluster', 'true'
  }

  tasks.register("${baseName}#upgradedClusterTest", RestTestRunnerTask) {
    useCluster testClusters."${baseName}"
    dependsOn "${baseName}#oldClusterTest"
    doFirst {
      testClusters."${baseName}".goToNextVersion()
    }
    systemProperty 'tests.is_old_cluster', 'false'
  }

  tasks.matching { it.name.startsWith(baseName) && it.name.endsWith("ClusterTest") }.configureEach {
    it.systemProperty 'tests.old_cluster_version', bwcVersion.toString().minus("-SNAPSHOT")
    it.systemProperty 'tests.path.repo', "${buildDir}/cluster/shared/repo/${baseName}"
    it.nonInputProperties.systemProperty('tests.rest.cluster', "${-> testClusters."${baseName}".allHttpSocketURI.join(",") }")
    it.nonInputProperties.systemProperty('tests.clustername', "${-> testClusters."${baseName}".getName() }")
  }

  if (project.bwc_tests_enabled) {
    bwcTest.dependsOn(
            tasks.register("${baseName}#bwcTest") {
              dependsOn tasks.named("${baseName}#upgradedClusterTest")
            }
    )
  }
}

test.enabled = false // no unit tests for rolling upgrades, only the rest integration test

// basic integ tests includes testing bwc against the most recent version
task bwcTestSnapshots {
  if (project.bwc_tests_enabled) {
    for (final def version : bwcVersions.unreleasedIndexCompatible) {
      dependsOn "v${version}#bwcTest"
    }
  }
}

check.dependsOn(bwcTestSnapshots)

configurations {
  testArtifacts.extendsFrom testRuntime
}

task testJar(type: Jar) {
  appendix 'test'
  from sourceSets.test.output
}

artifacts {
  testArtifacts testJar
}