OpenSearch/qa/smoke-test-watcher-with-security/build.gradle

apply plugin: 'elasticsearch.standalone-rest-test'
apply plugin: 'elasticsearch.rest-test'

dependencies {
  testCompile project(path: ':x-pack-elasticsearch:plugin', configuration: 'runtime')
}

// bring in watcher rest test suite
task copyWatcherRestTests(type: Copy) {
  into project.sourceSets.test.output.resourcesDir
  from project(':x-pack-elasticsearch:plugin').sourceSets.test.resources.srcDirs
  include 'rest-api-spec/test/watcher/**'
}

integTestRunner {
  systemProperty 'tests.rest.blacklist',
    ['hijack/10_basic/*',
     'getting_started/10_monitor_cluster_health/Getting started - Monitor cluster health'].join(',')
}

integTestCluster {
  dependsOn copyWatcherRestTests
  plugin ':x-pack-elasticsearch:plugin'
  extraConfigFile 'x-pack/roles.yml', 'roles.yml'
  setupCommand 'setupTestAdminUser',
               'bin/x-pack/users', 'useradd', 'test_admin', '-p', 'changeme', '-r', 'superuser'
  setupCommand 'setupWatcherManagerUser',
               'bin/x-pack/users', 'useradd', 'watcher_manager', '-p', 'changeme', '-r', 'watcher_manager'
  setupCommand 'setupPowerlessUser',
               'bin/x-pack/users', 'useradd', 'powerless_user', '-p', 'changeme', '-r', 'crappy_role'
  waitCondition = { node, ant ->
    File tmpFile = new File(node.cwd, 'wait.success')
    ant.get(src: "http://${node.httpUri()}/_cluster/health?wait_for_nodes=>=${numNodes}&wait_for_status=yellow",
            dest: tmpFile.toString(),
            username: 'test_admin',
            password: 'changeme',
            ignoreerrors: true,
            retries: 10)
    return tmpFile.exists()
  }
}