OpenSearch/qa/security-example-spi-extension/build.gradle

apply plugin: 'elasticsearch.esplugin'

esplugin {
  name 'spi-extension'
  description 'An example spi extension pluing for xpack security'
  classname 'org.elasticsearch.example.SpiExtensionPlugin'
  extendedPlugins = ['x-pack-security']
}

dependencies {
  compileOnly project(path: xpackModule('core'), configuration: 'runtime')
  testCompile project(path: xpackProject('transport-client').path, configuration: 'runtime')
}


integTestRunner {
    systemProperty 'tests.security.manager', 'false'
}

integTestCluster {
  dependsOn buildZip
  plugin xpackProject('plugin').path
  setting 'xpack.security.authc.realms.custom.order', '0'
  setting 'xpack.security.authc.realms.custom.type', 'custom'
  setting 'xpack.security.authc.realms.custom.filtered_setting', 'should be filtered'
  setting 'xpack.security.authc.realms.esusers.order', '1'
  setting 'xpack.security.authc.realms.esusers.type', 'file'
  setting 'xpack.security.authc.realms.native.type', 'native'
  setting 'xpack.security.authc.realms.native.order', '2'
  setting 'xpack.ml.enabled', 'false'
  setting 'xpack.monitoring.enabled', 'false'

  // This is important, so that all the modules are available too.
  // There are index templates that use token filters that are in analysis-module and
  // processors are being used that are in ingest-common module.
  distribution = 'zip'

  setupCommand 'setupDummyUser',
               'bin/x-pack/users', 'useradd', 'test_user', '-p', 'x-pack-test-password', '-r', 'superuser'
  waitCondition = { node, ant ->
    File tmpFile = new File(node.cwd, 'wait.success')
    ant.get(src: "http://${node.httpUri()}/_cluster/health?wait_for_nodes=>=${numNodes}&wait_for_status=yellow",
            dest: tmpFile.toString(),
            username: 'test_user',
            password: 'x-pack-test-password',
            ignoreerrors: true,
            retries: 10)
    return tmpFile.exists()
  }
}
check.dependsOn integTest