/*
 * Licensed to Elasticsearch under one or more contributor
 * license agreements. See the NOTICE file distributed with
 * this work for additional information regarding copyright
 * ownership. Elasticsearch licenses this file to you under
 * the Apache License, Version 2.0 (the "License"); you may
 * not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

import org.elasticsearch.gradle.test.RestIntegTestTask

apply plugin: 'elasticsearch.standalone-test'

dependencies {
  testCompile project(":client:rest-high-level")
}

task remoteClusterTest(type: RestIntegTestTask) {
  mustRunAfter(precommit)
}

remoteClusterTestCluster {
  numNodes = 2
  clusterName = 'remote-cluster'
  setting 'cluster.remote.connect', false
}

remoteClusterTestRunner {
  systemProperty 'tests.rest.suite', 'remote_cluster'
}

task mixedClusterTest(type: RestIntegTestTask) {}

mixedClusterTestCluster {
  dependsOn remoteClusterTestRunner
  setting 'cluster.remote.my_remote_cluster.seeds', "\"${-> remoteClusterTest.nodes.get(0).transportUri()}\""
  setting 'cluster.remote.connections_per_cluster', 1
  setting 'cluster.remote.connect', true
}

mixedClusterTestRunner {
  systemProperty 'tests.rest.suite', 'multi_cluster'
  finalizedBy 'remoteClusterTestCluster#node0.stop','remoteClusterTestCluster#node1.stop'
}

task integTest {
  dependsOn = [mixedClusterTest]
}

test.enabled = false // no unit tests for multi-cluster-search, only integration tests

check.dependsOn(integTest)