/*
 * Licensed to Elasticsearch under one or more contributor
 * license agreements. See the NOTICE file distributed with
 * this work for additional information regarding copyright
 * ownership. Elasticsearch licenses this file to you under
 * the Apache License, Version 2.0 (the "License"); you may
 * not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

import org.elasticsearch.gradle.test.RestIntegTestTask

apply plugin: 'elasticsearch.standalone-test'

task remoteClusterTest(type: RestIntegTestTask) {
  mustRunAfter(precommit)
  cluster {
    distribution = 'zip'
    numNodes = 2
    clusterName = 'remote-cluster'
    setting 'search.remote.connect', false
  }
  systemProperty 'tests.rest.suite', 'remote_cluster'
}

task mixedClusterTest(type: RestIntegTestTask) {
  dependsOn(remoteClusterTest)
  cluster {
    distribution = 'zip'
    setting 'search.remote.my_remote_cluster.seeds', "\"${-> remoteClusterTest.nodes.get(0).transportUri()}\""
    setting 'search.remote.connections_per_cluster', 1
    setting 'search.remote.connect', true
  }
  systemProperty 'tests.rest.suite', 'multi_cluster'
  finalizedBy 'remoteClusterTest#node0.stop','remoteClusterTest#node1.stop'
}

task integTest {
  dependsOn = [mixedClusterTest]
}

test.enabled = false // no unit tests for multi-cluster-search, only the rest integration test

check.dependsOn(integTest)