description = 'Code shared between jdbc and cli'

dependencies {
  compile project(':x-pack-elasticsearch:sql:rest-proto')
  compile "com.fasterxml.jackson.core:jackson-core:${versions.jackson}"
}

dependencyLicenses {
  mapping from: /jackson-.*/, to: 'jackson'
  mapping from: /rest-proto.*/, to: 'elasticsearch'
  mapping from: /shared-proto.*/, to: 'elasticsearch'
  mapping from: /elasticsearch-cli.*/, to: 'elasticsearch'
  mapping from: /lucene-.*/, to: 'lucene'
  ignoreSha 'rest-proto'
  ignoreSha 'shared-proto'
  ignoreSha 'elasticsearch'
}

forbiddenApisMain {
  // does not depend on core, so only jdk and http signatures should be checked
  signaturesURLs = [this.class.getResource('/forbidden/jdk-signatures.txt')]
}

forbiddenApisTest {
  bundledSignatures -= 'jdk-non-portable'
  bundledSignatures += 'jdk-internal'
}

forbiddenPatterns {
  exclude '**/*.keystore'
}

// Allow for com.sun.net.httpserver.* usage for testing
eclipse {
  classpath.file {
    whenMerged { cp ->
      def con = entries.find { e ->
        e.kind == "con" && e.toString().contains("org.eclipse.jdt.launching.JRE_CONTAINER")
      }
      con.accessRules.add(new org.gradle.plugins.ide.eclipse.model.AccessRule(
        "accessible", "com/sun/net/httpserver/*"))
    }
  }
}