/*
 * Licensed to Elasticsearch under one or more contributor
 * license agreements. See the NOTICE file distributed with
 * this work for additional information regarding copyright
 * ownership. Elasticsearch licenses this file to you under
 * the Apache License, Version 2.0 (the "License"); you may
 * not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

esplugin {
  description 'The Azure Discovery plugin allows to use Azure API for the unicast discovery mechanism.'
  classname 'org.elasticsearch.plugin.discovery.azure.AzureDiscoveryPlugin'
}

versions << [
  'azure': '0.9.0',
  'jersey': '1.13'
]

dependencies {
  compile "com.microsoft.azure:azure-svc-mgmt-compute:${versions.azure}"
  compile "com.microsoft.azure:azure-core:${versions.azure}"
  compile "org.apache.httpcomponents:httpclient:${versions.httpclient}"
  compile "org.apache.httpcomponents:httpcore:${versions.httpcore}"
  compile "commons-logging:commons-logging:${versions.commonslogging}"
  compile "commons-codec:commons-codec:${versions.commonscodec}"
  compile "commons-lang:commons-lang:2.6"
  compile "commons-io:commons-io:2.4"
  compile 'javax.mail:mail:1.4.5'
  compile 'javax.inject:javax.inject:1'
  compile "com.sun.jersey:jersey-client:${versions.jersey}"
  compile "com.sun.jersey:jersey-core:${versions.jersey}"
  compile "com.sun.jersey:jersey-json:${versions.jersey}"
  compile 'org.codehaus.jettison:jettison:1.1' 
  compile 'com.sun.xml.bind:jaxb-impl:2.2.3-1'
  compile 'org.codehaus.jackson:jackson-core-asl:1.9.2'
  compile 'org.codehaus.jackson:jackson-mapper-asl:1.9.2'
  compile 'org.codehaus.jackson:jackson-jaxrs:1.9.2'
  compile 'org.codehaus.jackson:jackson-xc:1.9.2'  
}

dependencyLicenses {
  mapping from: /azure-.*/, to: 'azure'
  mapping from: /jackson-.*/, to: 'jackson'
  mapping from: /jersey-.*/, to: 'jersey'
  mapping from: /jaxb-.*/, to: 'jaxb'
}

compileJava.options.compilerArgs << '-Xlint:-path,-serial,-static,-unchecked'
// TODO: why is deprecation needed here but not in maven....?
compileJava.options.compilerArgs << '-Xlint:-deprecation'
// TODO: and why does this static not show up in maven...
compileTestJava.options.compilerArgs << '-Xlint:-static'

// classes are missing, e.g. org.osgi.framework.BundleActivator
thirdPartyAudit.missingClasses = true
// TODO: figure out what is happening and fix this!!!!!!!!!!!
// there might be still some undetected jar hell!
// we need to fix https://github.com/policeman-tools/forbidden-apis/issues/91 first
thirdPartyAudit.excludes = [
    // uses internal java api: com.sun.xml.fastinfoset.stax.StAXDocumentParser
    'com.sun.xml.bind.v2.runtime.unmarshaller.FastInfosetConnector',
    'com.sun.xml.bind.v2.runtime.unmarshaller.FastInfosetConnector$CharSequenceImpl',
    // uses internal java api: com.sun.xml.fastinfoset.stax.StAXDocumentSerializer
    'com.sun.xml.bind.v2.runtime.output.FastInfosetStreamWriterOutput',
]