apply plugin: 'elasticsearch.rest-test'

dependencies {
  testCompile project(path: ':x-plugins:elasticsearch', configuration: 'runtime')
}

integTest {
  includePackaged true
  systemProperty 'tests.rest.blacklist',
    ['cat.aliases/10_basic/Empty cluster',
     'index/10_with_id/Index with ID',
     'indices.get_alias/10_basic/Get alias against closed indices',
     'cat.templates/10_basic/No templates',
     'cat.templates/10_basic/Sort templates'
    ].join(',')

  cluster {
    plugin ':x-plugins:elasticsearch'
    setting 'xpack.watcher.enabled', 'false'
    setting 'xpack.monitoring.enabled', 'false'
    setupCommand 'setupDummyUser',
                 'bin/x-pack/users', 'useradd', 'test_user', '-p', 'changeme', '-r', 'superuser'
    waitCondition = { node, ant ->
      File tmpFile = new File(node.cwd, 'wait.success')
      ant.get(src: "http://${node.httpUri()}",
              dest: tmpFile.toString(),
              username: 'test_user',
              password: 'changeme',
              ignoreerrors: true,
              retries: 10)
      return tmpFile.exists()
    }
  }
}