mirror of
https://github.com/honeymoose/OpenSearch.git
synced 2025-03-01 16:39:11 +00:00
65e5868a55
[test] add java packaging test project Adds a project for building and running packaging tests written in java for portability. The vagrant tasks use jars on the packagingTest configuration, which are built in the same project. No tests are added yet. Corresponding changes are not made to :x-pack:qa:vagrant because the java packaging tests will all be consolidated into one project. For #26741
76 lines
2.2 KiB
Groovy
76 lines
2.2 KiB
Groovy
import org.elasticsearch.gradle.precommit.PrecommitTasks
|
|
|
|
/*
|
|
* Licensed to Elasticsearch under one or more contributor
|
|
* license agreements. See the NOTICE file distributed with
|
|
* this work for additional information regarding copyright
|
|
* ownership. Elasticsearch licenses this file to you under
|
|
* the Apache License, Version 2.0 (the "License"); you may
|
|
* not use this file except in compliance with the License.
|
|
* You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing,
|
|
* software distributed under the License is distributed on an
|
|
* "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
|
|
* KIND, either express or implied. See the License for the
|
|
* specific language governing permissions and limitations
|
|
* under the License.
|
|
*/
|
|
|
|
plugins {
|
|
id 'java'
|
|
id 'elasticsearch.build'
|
|
id 'elasticsearch.vagrantsupport'
|
|
id 'elasticsearch.vagrant'
|
|
}
|
|
|
|
dependencies {
|
|
compile "junit:junit:${versions.junit}"
|
|
compile "org.hamcrest:hamcrest-core:${versions.hamcrest}"
|
|
|
|
// needs to be on the classpath for JarHell
|
|
testRuntime project(':libs:elasticsearch-core')
|
|
|
|
// pulls in the jar built by this project and its dependencies
|
|
packagingTest project(path: project.path, configuration: 'runtime')
|
|
}
|
|
|
|
List<String> plugins = []
|
|
for (Project subproj : project.rootProject.subprojects) {
|
|
if (subproj.parent.path == ':plugins' || subproj.path.equals(':example-plugins:custom-settings')) {
|
|
// add plugin as a dep
|
|
dependencies {
|
|
packaging project(path: "${subproj.path}", configuration: 'zip')
|
|
}
|
|
plugins.add(subproj.name)
|
|
}
|
|
}
|
|
plugins = plugins.toSorted()
|
|
|
|
setupPackagingTest {
|
|
doFirst {
|
|
File expectedPlugins = file('build/plugins/expected')
|
|
expectedPlugins.parentFile.mkdirs()
|
|
expectedPlugins.setText(plugins.join('\n'), 'UTF-8')
|
|
}
|
|
}
|
|
|
|
esvagrant {
|
|
testClass 'org.elasticsearch.packaging.PackagingTests'
|
|
}
|
|
|
|
forbiddenApisMain {
|
|
signaturesURLs = [
|
|
PrecommitTasks.getResource('/forbidden/jdk-signatures.txt')
|
|
]
|
|
}
|
|
|
|
// we don't have additional tests for the tests themselves
|
|
tasks.test.enabled = false
|
|
|
|
// this project doesn't get published
|
|
tasks.dependencyLicenses.enabled = false
|
|
tasks.dependenciesInfo.enabled = false
|