mirror of
https://github.com/honeymoose/OpenSearch.git
synced 2025-02-14 17:05:36 +00:00
49e30b15a2
We believe there's no longer a need to be able to disable basic-license features completely using the "xpack.*.enabled" settings. If users don't want to use those features, they simply don't need to use them. Having such features always available lets us build more complex features that assume basic-license features are present. This commit deprecates settings of the form "xpack.*.enabled" for basic-license features, excluding "security", which is a special case. It also removes deprecated settings from integration tests and unit tests where they're not directly relevant; e.g. monitoring and ILM are no longer disabled in many integration tests.
63 lines
1.7 KiB
Groovy
63 lines
1.7 KiB
Groovy
import org.elasticsearch.gradle.test.RestIntegTestTask
|
|
|
|
apply plugin: 'elasticsearch.testclusters'
|
|
apply plugin: 'elasticsearch.standalone-test'
|
|
|
|
dependencies {
|
|
testCompile project(':x-pack:qa')
|
|
testCompile project(':client:rest-high-level')
|
|
}
|
|
|
|
restResources {
|
|
restApi {
|
|
includeXpack 'security', 'transform'
|
|
}
|
|
}
|
|
|
|
task 'remote-cluster'(type: RestIntegTestTask) {
|
|
mustRunAfter(precommit)
|
|
runner {
|
|
systemProperty 'tests.rest.suite', 'remote_cluster'
|
|
}
|
|
}
|
|
|
|
testClusters.'remote-cluster' {
|
|
testDistribution = 'DEFAULT'
|
|
numberOfNodes = 2
|
|
setting 'node.remote_cluster_client', "false"
|
|
setting 'xpack.security.enabled', 'true'
|
|
setting 'xpack.watcher.enabled', 'false'
|
|
setting 'xpack.license.self_generated.type', 'trial'
|
|
|
|
user username: "test_user", password: "x-pack-test-password"
|
|
}
|
|
|
|
task 'mixed-cluster'(type: RestIntegTestTask) {
|
|
dependsOn 'remote-cluster'
|
|
runner {
|
|
useCluster testClusters.'remote-cluster'
|
|
systemProperty 'tests.rest.suite', 'multi_cluster'
|
|
}
|
|
}
|
|
|
|
testClusters.'mixed-cluster' {
|
|
testDistribution = 'DEFAULT'
|
|
setting 'xpack.security.enabled', 'true'
|
|
setting 'xpack.watcher.enabled', 'false'
|
|
setting 'xpack.license.self_generated.type', 'trial'
|
|
setting 'cluster.remote.my_remote_cluster.seeds', {
|
|
testClusters.'remote-cluster'.getAllTransportPortURI().collect { "\"$it\"" }.toString()
|
|
}
|
|
setting 'cluster.remote.connections_per_cluster', "1"
|
|
setting 'node.remote_cluster_client', "true"
|
|
|
|
user username: "test_user", password: "x-pack-test-password"
|
|
}
|
|
|
|
task integTest {
|
|
dependsOn 'mixed-cluster'
|
|
}
|
|
|
|
test.enabled = false // no unit tests for multi-cluster-search, only the rest integration test
|
|
check.dependsOn(integTest)
|