mirror of
https://github.com/honeymoose/OpenSearch.git
synced 2025-02-10 06:55:32 +00:00
d8dad9ab2c
This commit removes `integTest` task from all es-plugins. Most relevant projects have been converted to use yamlRestTest, javaRestTest, or internalClusterTest in prior PRs. A few projects needed to be adjusted to allow complete removal of this task * x-pack/plugin - converted to use yamlRestTest and javaRestTest * plugins/repository-hdfs - kept the integTest task, but use `rest-test` plugin to define the task * qa/die-with-dignity - convert to javaRestTest * x-pack/qa/security-example-spi-extension - convert to javaRestTest * multiple projects - remove the integTest.enabled = false (yay!) related: #61802 related: #60630 related: #59444 related: #59089 related: #56841 related: #59939 related: #55896
50 lines
1.5 KiB
Groovy
50 lines
1.5 KiB
Groovy
apply plugin: 'elasticsearch.esplugin'
|
|
apply plugin: 'elasticsearch.internal-cluster-test'
|
|
esplugin {
|
|
name 'x-pack-ccr'
|
|
description 'Elasticsearch Expanded Pack Plugin - CCR'
|
|
classname 'org.elasticsearch.xpack.ccr.Ccr'
|
|
hasNativeController false
|
|
requiresKeystore true
|
|
extendedPlugins = ['x-pack-core']
|
|
}
|
|
archivesBaseName = 'x-pack-ccr'
|
|
|
|
// Integration Test classes that cannot run with the security manager
|
|
String[] noSecurityManagerITClasses = ["**/CloseFollowerIndexIT.class"]
|
|
|
|
tasks.register('internalClusterTestNoSecurityManager', Test) {
|
|
testClassesDirs = sourceSets.internalClusterTest.output.classesDirs
|
|
classpath = sourceSets.internalClusterTest.runtimeClasspath
|
|
include noSecurityManagerITClasses
|
|
systemProperty 'tests.security.manager', 'false'
|
|
}
|
|
check.dependsOn 'internalClusterTestNoSecurityManager'
|
|
|
|
tasks.named('internalClusterTest').configure {
|
|
exclude noSecurityManagerITClasses
|
|
}
|
|
|
|
// add all sub-projects of the qa sub-project
|
|
gradle.projectsEvaluated {
|
|
project.subprojects
|
|
.find { it.path == project.path + ":qa" }
|
|
.subprojects
|
|
.findAll { it.path.startsWith(project.path + ":qa") }
|
|
.each { check.dependsOn it.check }
|
|
}
|
|
|
|
dependencies {
|
|
compileOnly project(":server")
|
|
|
|
compileOnly project(path: xpackModule('core'), configuration: 'default')
|
|
testImplementation project(path: xpackModule('core'), configuration: 'testArtifacts')
|
|
testImplementation project(path: xpackModule('monitoring'), configuration: 'testArtifacts')
|
|
}
|
|
|
|
testingConventions.naming {
|
|
IT {
|
|
baseClass "org.elasticsearch.xpack.CcrIntegTestCase"
|
|
}
|
|
}
|