mirror of
https://github.com/honeymoose/OpenSearch.git
synced 2025-03-02 17:09:18 +00:00
634a070430
* Restrict which tasks can use testclusters This PR fixes a problem between the interaction of test-clusters and build cache. Before this any task could have used a cluster without tracking it as input. With this change a new interface is introduced to track the tasks that can use clusters and we do consider the cluster as input for all of them.
53 lines
1.8 KiB
Groovy
53 lines
1.8 KiB
Groovy
import org.elasticsearch.gradle.test.RestIntegTestTask
|
|
|
|
apply plugin: 'elasticsearch.testclusters'
|
|
apply plugin: 'elasticsearch.standalone-test'
|
|
|
|
dependencies {
|
|
testCompile project(path: xpackModule('core'), configuration: 'testArtifacts')
|
|
testCompile project(path: xpackModule('ccr'), configuration: 'runtime')
|
|
testCompile project(':x-pack:plugin:ccr:qa')
|
|
}
|
|
|
|
task 'leader-cluster'(type: RestIntegTestTask) {
|
|
mustRunAfter(precommit)
|
|
runner {
|
|
systemProperty 'tests.target_cluster', 'leader'
|
|
}
|
|
}
|
|
|
|
testClusters.'leader-cluster' {
|
|
testDistribution = 'DEFAULT'
|
|
setting 'xpack.license.self_generated.type', 'trial'
|
|
setting 'xpack.security.enabled', 'true'
|
|
setting 'xpack.monitoring.enabled', 'false'
|
|
extraConfigFile 'roles.yml', file('leader-roles.yml')
|
|
user username: "test_admin", role: "superuser"
|
|
user username: "test_ccr", role: "ccruser"
|
|
}
|
|
|
|
task 'follow-cluster'(type: RestIntegTestTask) {
|
|
dependsOn 'leader-cluster'
|
|
runner {
|
|
useCluster testClusters.'leader-cluster'
|
|
systemProperty 'tests.target_cluster', 'follow'
|
|
nonInputProperties.systemProperty 'tests.leader_host', "${-> testClusters.'leader-cluster'.getAllHttpSocketURI().get(0)}"
|
|
}
|
|
}
|
|
|
|
testClusters.'follow-cluster' {
|
|
testDistribution = 'DEFAULT'
|
|
setting 'cluster.remote.leader_cluster.seeds', {
|
|
"\"${testClusters.'leader-cluster'.getAllTransportPortURI().join(",")}\""
|
|
}
|
|
setting 'xpack.license.self_generated.type', 'trial'
|
|
setting 'xpack.security.enabled', 'true'
|
|
setting 'xpack.monitoring.collection.enabled', 'true'
|
|
extraConfigFile 'roles.yml', file('follower-roles.yml')
|
|
user username: "test_admin", role: "superuser"
|
|
user username: "test_ccr", role: "ccruser"
|
|
}
|
|
|
|
check.dependsOn 'follow-cluster'
|
|
test.enabled = false // no unit tests for multi-cluster-search, only the rest integration test
|