OpenSearch/marvel/build.gradle

import org.elasticsearch.gradle.MavenFilteringHack

apply plugin: 'elasticsearch.esplugin'
esplugin {
  name 'marvel-agent'
  description 'Elasticsearch Marvel'
  classname 'org.elasticsearch.marvel.MarvelPlugin'
  isolated false
}

configurations {
  licensePluginZip
}

dependencies {
  licensePluginZip project(path: ':license:plugin') // zip
  provided project(path: ':license:plugin', configuration: 'runtime')
  provided project(path: ':shield', configuration: 'runtime')
  testCompile 'org.elasticsearch:securemock:1.1'
  testCompile 'com.squareup.okhttp:mockwebserver:2.3.0'
}

compileJava.options.compilerArgs << '-Xlint:-rawtypes,-unchecked'
compileTestJava.options.compilerArgs << '-Xlint:-rawtypes,-unchecked'

ext.expansions = [
  'project.version': version,
  'integ.http.port': integTest.cluster.httpPort
]

processResources {
  inputs.properties(expansions)
  MavenFilteringHack.filter(it, expansions)
}

processTestResources {
  inputs.properties(expansions)
  MavenFilteringHack.filter(it, expansions)
}

integTest {
  dependsOn configurations.licensePluginZip
  cluster {
    plugin 'installLicensePlugin', configurations.licensePluginZip
  }
}

bundlePlugin {
  from(projectDir) {
    include 'LICENSE.txt'
    include 'NOTICE.txt'
  }
}