68 lines
4.8 KiB
Mathematica
68 lines
4.8 KiB
Mathematica
DVBAB6 ;ALB/KLB - CAPRI PENDING 2507 REQUEST ;08/01/00
|
|
;;2.7;AMIE;**35,90,108**;Apr 10, 1995
|
|
;
|
|
STRT(MSG,DVBCSORT,RSTAT,ERDAYS,OLDAYS,ADIVNUM,ELTYP) ;
|
|
I ADIVNUM'="" S X=$O(^DG(40.8,"C",ADIVNUM,"")) S:X]"" ADIVNUM=X
|
|
SETUP K ^TMP($J),^TMP("CAPRI")
|
|
S DVBCDT(0)=$$FMTE^XLFDT(DT,"5DZ"),PG=1,DVBCCNT=0,DONE="NO",MSGCNT=1
|
|
S DVBCHDR="Sorted by "_$S(DVBCSORT="V":"VETERAN NAME",DVBCSORT="R":"Routing location",DVBCSORT="S":"Status",DVBCSORT="A":"Age of request",1:"Unknown")
|
|
HEAD S HEAD="Pending 2507 Requests for "_$S($D(^DVB(396.1,1,0)):$P(^(0),U,1),1:"Unknown site"),HEAD2="",PROCDT="Processed on: "_DVBCDT(0),NODATA=0
|
|
S ^TMP("CAPRI",MSGCNT)=HEAD_"^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)=HEAD2_"^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)=PROCDT_"^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)="^",MSGCNT=MSGCNT+1
|
|
S $P(^TMP("CAPRI",MSGCNT),"=",75)="=^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)="^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)="",MSGCNT=MSGCNT+1
|
|
DATA S DFN="" F S DFN=$O(^DVB(396.3,"B",DFN)) Q:DFN="" F REQDA=0:0 S REQDA=$O(^DVB(396.3,"B",DFN,REQDA)) Q:REQDA="" D SORT^DVBAB5
|
|
I DVBCSORT="V" S PNAM="" F S PNAM=$O(^TMP($J,PNAM)) Q:PNAM="" F DFN=0:0 S DFN=$O(^TMP($J,PNAM,DFN)) Q:'DFN F DA(1)=0:0 S DA(1)=$O(^TMP($J,PNAM,DFN,DA(1))) Q:'DA(1) D PRINT I $D(OUT) S DA(1)=999999999,PNAM="ZZZ",DONE="YES" Q
|
|
I DVBCSORT="R"!(DVBCSORT="A")!(DVBCSORT="S") D
|
|
. S JX="" F S JX=$O(^TMP($J,JX)) Q:JX="" D
|
|
.. S PNAM="" F S PNAM=$O(^TMP($J,JX,PNAM)) Q:PNAM="" D
|
|
... F DFN=0:0 S DFN=$O(^TMP($J,JX,PNAM,DFN)) Q:'DFN D NXT
|
|
I DVBCCNT>0 S ^TMP("CAPRI",MSGCNT)="Total pending: "_DVBCCNT,DONE="YES"
|
|
;
|
|
EXIT I NODATA=0 S ^TMP("CAPRI",MSGCNT)="No pending request found for select parameters.",MSG=$NA(^TMP("CAPRI"))
|
|
I DONE="YES" S MSG=$NA(^TMP("CAPRI"))
|
|
K ^TMP($J),ADIV,CNUM,NODATA,STATUS,TST,TSTA1,STSAT,KKMSGCNT,PG,PRTNM,RDATE,RDATE1,REQDA,SSN,RONAME,JX
|
|
K PROCDT,REQSTR,TSTAT,DA,DFN,DONE,DVBCCNT,DVBCDT,DVBCHDR,X,XX,ZS,ZZZ,HEAD,HEAD2,OUT,OWNDOM,EDAYS,PNAM
|
|
Q
|
|
;
|
|
PRINT S ADIV=$S($D(^DVB(396.3,DA(1),1)):$P(^(1),U,4),1:"") Q:ADIV'=ADIVNUM&(DVBCSORT="R") I ADIV]"" S ADIV=$S($D(^DG(40.8,+ADIV,0)):$P(^(0),U,1),1:"Unknown Division")
|
|
S RDATE1=$P(^DVB(396.3,DA(1),0),U,2),RDATE=$P(^(0),U,5)
|
|
S SSN=$P($G(^DPT(DFN,0)),U,9) S:SSN="" SSN="Unknown"
|
|
S CNUM=$P($G(^DPT(DFN,.31)),U,3) S:CNUM="" CNUM="Unknown"
|
|
D ELAPSED^DVBAB5
|
|
S STATUS="Unknown",^TMP("CAPRI",MSGCNT)="Division: "_ADIV_"^",MSGCNT=MSGCNT+1,XX=$P(^DVB(396.3,DA(1),0),U,18),STATUS=$S(XX="N":"New",XX="P":"Pending, reported",XX="S":"Pending, scheduled",XX="R":"Released to RO, not printed",1:"")
|
|
I STATUS="",$D(XX) S STATUS=$S(XX="C":"Completed, printed by RO",XX="X":"Cancelled by RO",XX="T":"Transcribed",XX="NT":"New,Transferred in",XX="CT":"Completed, Transferred out",1:"Unknown")
|
|
S ^TMP("CAPRI",MSGCNT)="Status: "_STATUS_"^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)=PNAM_" ^",MSGCNT=MSGCNT+1,^TMP("CAPRI",MSGCNT)="SSN: "_SSN_"^",MSGCNT=MSGCNT+1,^TMP("CAPRI",MSGCNT)="Claim no: "_CNUM_"^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)="Request Date: "_$$FMTE^XLFDT(RDATE1,"5DZ")_"^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)="Elapsed days: "_EDAYS_"^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)="^",MSGCNT=MSGCNT+1
|
|
S X=$S($D(^DVB(396.3,DA(1),4)):^(4),1:"")
|
|
S OWNDOM=$P(^DVB(396.3,DA(1),0),U,22) I OWNDOM]"" S ^TMP("CAPRI",MSGCNT)="Transferred in from "_$S($D(^DIC(4.2,+OWNDOM,0)):$P(^(0),U,1),1:"Unknown Site")_"^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)="^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)="Exams requested:"_"^",MSGCNT=MSGCNT+1
|
|
;
|
|
ITEMS D TST S NODATA=1,REQSTR=+$P(^DVB(396.3,DA(1),0),U,4)
|
|
S ZZZ="Requested by: "_$S($D(^VA(200,+REQSTR,0)):$P(^(0),U,1),1:" (Not specified) ")_" at "
|
|
S RONAME=$P(^DVB(396.3,DA(1),0),U,3),RONAME=$S(RONAME]"":$P(^DIC(4,+RONAME,0),U,1),1:"")
|
|
S ^TMP("CAPRI",MSGCNT)="^"_ZZZ_$S(RONAME]"":RONAME,1:" (Not specified) ")_"^",MSGCNT=MSGCNT+1
|
|
S ^TMP("CAPRI",MSGCNT)="^",MSGCNT=MSGCNT+1
|
|
S $P(^TMP("CAPRI",MSGCNT),"-",75)="-^",MSGCNT=MSGCNT+1
|
|
S DVBCCNT=DVBCCNT+1,MSGCNT=MSGCNT+1
|
|
Q
|
|
NXT F DA(1)=0:0 S DA(1)=$O(^TMP($J,JX,PNAM,DFN,DA(1))) Q:DA(1)="" D PRINT I $D(OUT) S DA(1)="",PNAM="ZZZZ",JX=$S($A(JX)>57:PNAM,1:9999999),DONE="YES"
|
|
Q
|
|
TST F DA=0:0 S DA=$O(^DVB(396.4,"C",DA(1),DA)) Q:DA="" K PRINT S TSTAT=$P(^DVB(396.4,DA,0),U,4),TST=$P(^DVB(396.4,DA,0),U,3),PRTNM=$S($D(^DVB(396.6,TST,0)):$P(^(0),U,2),1:"") D TST1
|
|
Q
|
|
TST1 S TSTA1=""
|
|
I $D(^DVB(396.4,DA,"CAN")) S TSTA1=$P(^DVB(396.4,DA,"CAN"),U,3)
|
|
I $D(^DVB(396.4,DA,"TRAN")) S X=$P(^DVB(396.4,DA,"TRAN"),U,3)
|
|
S:TSTA1]"" TSTA1=$P(^DVB(396.5,TSTA1,0),U,1)
|
|
S ^TMP("CAPRI",MSGCNT)=$S(PRTNM]"":PRTNM,1:"Missing exam name")_$S(TSTA1]"":" -cancelled ("_TSTA1_")",TSTAT="T":" - Transferred",TSTAT="":" (Unknown status)",1:"")_"^",MSGCNT=MSGCNT+1
|
|
I TSTAT="T" S X=$S($D(^DIC(4.2,+X,0)):$P(^(0),U,1),1:"unknown site") S ^TMP("CAPRI",MSGCNT)=" to "_$P(X,".",1),MSGCNT=MSGCNT+1
|
|
;S ^TMP("CAPRI",MSGCNT)=";",MSGCNT=MSGCNT+1
|
|
Q
|