GPLPROBS ; CCDCCR/GPL - CCR/CCD PROCESSING FOR PROBLEMS ; 6/6/08
 ;;0.1;CCDCCR;nopatch;noreleasedate
 ;Copyright 2008 WorldVistA.  Licensed under the terms of the GNU
 ;General Public License See attached copy of the License.
 ;
 ;This program is free software; you can redistribute it and/or modify
 ;it under the terms of the GNU General Public License as published by
 ;the Free Software Foundation; either version 2 of the License, or
 ;(at your option) any later version.
 ;
 ;This program is distributed in the hope that it will be useful,
 ;but WITHOUT ANY WARRANTY; without even the implied warranty of
 ;MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 ;GNU General Public License for more details.
 ;
 ;You should have received a copy of the GNU General Public License along
 ;with this program; if not, write to the Free Software Foundation, Inc.,
 ;51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
 ;
           ;
           ;  PROCESS THE PROBLEMS SECTION OF THE CCR
           ;
EXTRACT(IPXML,DFN,OUTXML) ; EXTRACT PROBLEMS INTO PROVIDED XML TEMPLATE
          ;
          ; INXML AND OUTXML ARE PASSED BY NAME SO GLOBALS CAN BE USED
          ; INXML WILL CONTAIN ONLY THE PROBLEM SECTION OF THE OVERALL TEMPLATE
          ; ONLY THE XML FOR ONE PROBLEM WILL BE PASSED. THIS ROUTINE WILL MAKE
          ; COPIES AS NECESSARY TO REPRESENT MULTIPLE PROBLEMS
          ; INSERT^GPLXPATH IS USED TO APPEND THE PROBLEMS TO THE OUTPUT
          ;
          N RPCRSLT,J,K,PTMP,X,VMAP,TBUF
          D LIST^ORQQPL3(.RPCRSLT,DFN,"") ; CALL THE PROBLEM LIST RPC
          I '$D(RPCRSLT(0)) W "ERROR CALLING LIST^ORQQPL3 ",! Q
          ZWR RPCRSLT
          S TVMAP=$NA(^TMP("GPLCCR",$J,"PROBVALS"))
          S TARYTMP=$NA(^TMP("GPLCCR",$J,"PROBARYTMP"))
          F J=1:1:RPCRSLT(0)  D  ; FOR EACH PROBLEM IN THE LIST
          . S VMAP=$NA(@TVMAP@(J))
          . K @VMAP
          . I DEBUG W "VMAP= ",VMAP,!
          . S PTMP=RPCRSLT(J) ; PULL OUT PROBLEM FROM RPC RETURN ARRAY
          . S @VMAP@("PROBLEMOBJECTID")="PROBLEM"_J ; UNIQUE OBJID FOR PROBLEM
          . S @VMAP@("PROBLEMIEN")=$P(PTMP,U,1)
          . S @VMAP@("PROBLEMSTATUS")=$P(PTMP,U,2)
          . S @VMAP@("PROBLEMDESCRIPTION")=$P(PTMP,U,3)
          . S @VMAP@("PROBLEMCODEVALUE")=$P(PTMP,U,4)
          . S @VMAP@("PROBLEMDATEOFONSET")=$P(PTMP,U,5)
          . S @VMAP@("PROBLEMDATEMOD")=$P(PTMP,U,6)
          . S @VMAP@("PROBLEMSC")=$P(PTMP,U,7)
          . S @VMAP@("PROBLEMSE")=$P(PTMP,U,8)
          . S @VMAP@("PROBLEMCONDITION")=$P(PTMP,U,9)
          . S @VMAP@("PROBLEMLOC")=$P(PTMP,U,10)
          . S @VMAP@("PROBLEMLOCTYPE")=$P(PTMP,U,11)
          . S @VMAP@("PROBLEMPROVIDER")=$P(PTMP,U,12)
          . S X=@VMAP@("PROBLEMPROVIDER") ; FORMAT Y;NAME Y IS IEN OF PROVIDER
          . S @VMAP@("PROBLEMSOURCEACTORID")="ACTORPROVIDER_"_$P(X,";",1)
          . S @VMAP@("PROBLEMSERVICE")=$P(PTMP,U,13)
          . S @VMAP@("PROBLEMHASCMT")=$P(PTMP,U,14)
          . S @VMAP@("PROBLEMDTREC")=$P(PTMP,U,15)
          . S @VMAP@("PROBLEMINACT")=$P(PTMP,U,16)
          . S ARYTMP=$NA(@TARYTMP@(J))
          . ; W "ARYTMP= ",ARYTMP,!
          . K @ARYTMP
          . D MAP^GPLXPATH(IPXML,VMAP,ARYTMP) ;
          . I J=1 D  ; FIRST ONE IS JUST A COPY
          . . ; W "FIRST ONE",!
          . . D CP^GPLXPATH(ARYTMP,OUTXML)
          . . ; W "OUTXML ",OUTXML,!
          . I J>1 D  ; AFTER THE FIRST, INSERT INNER XML
          . . D INSINNER^GPLXPATH(OUTXML,ARYTMP)
          ; ZWR ^TMP("GPLCCR",$J,"PROBVALS",*)
          ; ZWR ^TMP("GPLCCR",$J,"PROBARYTMP",*) ; SHOW THE RESULTS
          ; ZWR @OUTXML
          ; $$HTML^DILF(
          ; GENERATE THE NARITIVE HTML FOR THE CCD
          I CCD D  ; IF THIS IS FOR A CCD
          . N HTMP,I,ZX
          . S ZX="<text><table border=""1"" width=""100%""><thead><tr><th>Condition</th><th>Effective Dates</th><th>Condition Status</th></tr></thead><tbody>"
          . D PUSH^GPLXPATH("HTMP",ZX) ; HEADER OF THE TABLE
          . F I=1:1:RPCRSLT(0) D  ; FOR EACH PROBLEM
          . . S VMAP=$NA(@TVMAP@(I))
          . . S ZX="<tr><td>" ; BEGIN ROW AND COL
          . . S ZX=ZX_@VMAP@("PROBLEMDESCRIPTION")
          . . S ZX=ZX_"</td><td>" ; NEXT COL
          . . D PUSH^GPLXPATH("HTMP",ZX) ; ADD TO BUFFER
          . . S ZX=@VMAP@("PROBLEMDATEOFONSET")
          . . I ZX="" S ZX="Unknown" ; SET TO UNKNOWN
          . . D PUSH^GPLXPATH("HTMP",ZX)
          . . S ZX="</td><td>" ; NEXT COL
          . . S ZX=ZX_"Active" ; WE ONLY DO ACTIVE
          . . S ZX=ZX_"</td></tr>" ; END OF COL AND ROW
          . . D PUSH^GPLXPATH("HTMP",ZX)
          . D PUSH^GPLXPATH("HTMP","</tbody></table></text>") ; END TABLE
          . D INSB4^GPLXPATH(OUTXML,"HTMP") ; INSERT AT TOP OF SECTION
          N PROBSTMP,I
          D MISSING^GPLXPATH(ARYTMP,"PROBSTMP") ; SEARCH XML FOR MISSING VARS
          I PROBSTMP(0)>0  D  ; IF THERE ARE MISSING VARS -
          . ; STRINGS MARKED AS @@X@@
          . W "PROBLEMS Missing list: ",!
          . F I=1:1:PROBSTMP(0) W PROBSTMP(I),!
          Q
          ;