64 lines
2.6 KiB
Mathematica
64 lines
2.6 KiB
Mathematica
GPLPROBS ; CCDCCR/GPL - CCR/CCD PROCESSING FOR PROBLEMS ; 6/6/08
|
|
;;0.1;CCDCCR;nopatch;noreleasedate
|
|
;
|
|
; PROCESS THE PROBLEMS SECTION OF THE CCR
|
|
;
|
|
EXTRACT(IPXML,DFN,OUTXML) ; EXTRACT PROBLEMS INTO PROVIDED XML TEMPLATE
|
|
;
|
|
; INXML AND OUTXML ARE PASSED BY NAME SO GLOBALS CAN BE USED
|
|
; INXML WILL CONTAIN ONLY THE PROBLEM SECTION OF THE OVERALL TEMPLATE
|
|
; ONLY THE XML FOR ONE PROBLEM WILL BE PASSED. THIS ROUTINE WILL MAKE
|
|
; COPIES AS NECESSARY TO REPRESENT MULTIPLE PROBLEMS
|
|
; INSERT^GPLXPATH IS USED TO APPEND THE PROBLEMS TO THE OUTPUT
|
|
;
|
|
N RPCRSLT,J,K,PTMP,X,VMAP,TBUF
|
|
D LIST^ORQQPL3(.RPCRSLT,DFN,"") ; CALL THE PROBLEM LIST RPC
|
|
I '$D(RPCRSLT(0)) W "ERROR CALLING LIST^ORQQPL3 ",! Q
|
|
I DEBUG ZWR RPCRSLT
|
|
S TVMAP=$NA(^TMP($J,"PROBVALS"))
|
|
S TARYTMP=$NA(^TMP($J,"PROBARYTMP"))
|
|
F J=1:1:RPCRSLT(0) D ; FOR EACH PROBLEM IN THE LIST
|
|
. S VMAP=$NA(@TVMAP@(J))
|
|
. K @VMAP
|
|
. I DEBUG W "VMAP= ",VMAP,!
|
|
. S PTMP=RPCRSLT(J) ; PULL OUT PROBLEM FROM RPC RETURN ARRAY
|
|
. S @VMAP@("PROBLEMOBJECTID")="PROBLEM"_J ; UNIQUE OBJID FOR PROBLEM
|
|
. S @VMAP@("PROBLEMIEN")=$P(PTMP,U,1)
|
|
. S @VMAP@("PROBLEMSTATUS")=$P(PTMP,U,2)
|
|
. S @VMAP@("PROBLEMDESCRIPTION")=$P(PTMP,U,3)
|
|
. S @VMAP@("PROBLEMCODEVALUE")=$P(PTMP,U,4)
|
|
. S @VMAP@("PROBLEMDATEOFONSET")=$P(PTMP,U,5)
|
|
. S @VMAP@("PROBLEMDATEMOD")=$P(PTMP,U,6)
|
|
. S @VMAP@("PROBLEMSC")=$P(PTMP,U,7)
|
|
. S @VMAP@("PROBLEMSE")=$P(PTMP,U,8)
|
|
. S @VMAP@("PROBLEMCONDITION")=$P(PTMP,U,9)
|
|
. S @VMAP@("PROBLEMLOC")=$P(PTMP,U,10)
|
|
. S @VMAP@("PROBLEMLOCTYPE")=$P(PTMP,U,11)
|
|
. S @VMAP@("PROBLEMPROVIDER")=$P(PTMP,U,12)
|
|
. S X=@VMAP@("PROBLEMPROVIDER") ; FORMAT Y;NAME Y IS IEN OF PROVIDER
|
|
. S @VMAP@("PROBLEMSOURCEACTORID")="ACTORPROVIDER_"_$P(X,";",1)
|
|
. S @VMAP@("PROBLEMSERVICE")=$P(PTMP,U,13)
|
|
. S @VMAP@("PROBLEMHASCMT")=$P(PTMP,U,14)
|
|
. S @VMAP@("PROBLEMDTREC")=$P(PTMP,U,15)
|
|
. S @VMAP@("PROBLEMINACT")=$P(PTMP,U,16)
|
|
. S ARYTMP=$NA(@TARYTMP@(J))
|
|
. ; W "ARYTMP= ",ARYTMP,!
|
|
. K @ARYTMP
|
|
. D MAP^GPLXPATH(IPXML,VMAP,ARYTMP) ;
|
|
. I J=1 D ; FIRST ONE IS JUST A COPY
|
|
. . ; W "FIRST ONE",!
|
|
. . D CP^GPLXPATH(ARYTMP,OUTXML)
|
|
. . ; W "OUTXML ",OUTXML,!
|
|
. I J>1 D ; AFTER THE FIRST, INSERT INNER XML
|
|
. . D INSINNER^GPLXPATH(OUTXML,ARYTMP)
|
|
; ZWR ^TMP($J,"PROBVALS",*)
|
|
; ZWR ^TMP($J,"PROBARYTMP",*) ; SHOW THE RESULTS
|
|
; ZWR @OUTXML
|
|
; $$HTML^DILF(
|
|
N PROBSTMP,I
|
|
D MISSING^GPLXPATH(ARYTMP,"PROBSTMP") ; SEARCH XML FOR MISSING VARS
|
|
I PROBSTMP(0)>0 D ; IF THERE ARE MISSING VARS - STRINGS MARKED AS @@X@@
|
|
. W "PROBLEMS Missing list: ",!
|
|
. F I=1:1:PROBSTMP(0) W PROBSTMP(I),!
|
|
Q
|