OpenSearch/plugins/discovery-ec2/build.gradle

/*
 * Licensed to Elasticsearch under one or more contributor
 * license agreements. See the NOTICE file distributed with
 * this work for additional information regarding copyright
 * ownership. Elasticsearch licenses this file to you under
 * the Apache License, Version 2.0 (the "License"); you may
 * not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

esplugin {
  description 'The EC2 discovery plugin allows to use AWS API for the unicast discovery mechanism.'
  classname 'org.elasticsearch.plugin.discovery.ec2.Ec2DiscoveryPlugin'
}

versions << [
  'aws': '1.10.33'
]

dependencies {
  compile "com.amazonaws:aws-java-sdk-ec2:${versions.aws}"
  compile "com.amazonaws:aws-java-sdk-core:${versions.aws}"
  compile "org.apache.httpcomponents:httpclient:${versions.httpclient}"
  compile "org.apache.httpcomponents:httpcore:${versions.httpcore}"
  compile "commons-logging:commons-logging:${versions.commonslogging}"
  compile "commons-codec:commons-codec:${versions.commonscodec}"
  compile 'com.fasterxml.jackson.core:jackson-databind:2.5.3'
  compile 'com.fasterxml.jackson.core:jackson-annotations:2.5.0'
}

dependencyLicenses {
  mapping from: /aws-java-sdk-.*/, to: 'aws-java-sdk'
  mapping from: /jackson-.*/, to: 'jackson'
}

compileJava.options.compilerArgs << '-Xlint:-rawtypes,-deprecation'

test {
  // this is needed for insecure plugins, remove if possible!
  systemProperty 'tests.artifact', project.name 
}

// classes are missing, e.g. org.apache.avalon.framework.logger.Logger
thirdPartyAudit.lenient = true
thirdPartyAudit.excludes = [
    // uses internal java api: com.sun.org.apache.xerces.internal.jaxp.DocumentBuilderFactoryImpl
    // uses internal java api: com.sun.org.apache.xml.internal.dtm.ref.DTMManagerDefault
    // uses internal java api: com.sun.org.apache.xpath.internal.XPathContext
    'com.amazonaws.util.XpathUtils',
]