OpenSearch/plugins/mapper-attachments/build.gradle

/*
 * Licensed to Elasticsearch under one or more contributor
 * license agreements. See the NOTICE file distributed with
 * this work for additional information regarding copyright
 * ownership. Elasticsearch licenses this file to you under
 * the Apache License, Version 2.0 (the "License"); you may
 * not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *    http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

esplugin {
  description 'The mapper attachments plugin adds the attachment type to Elasticsearch using Apache Tika.'
  classname 'org.elasticsearch.mapper.attachments.MapperAttachmentsPlugin'
}

versions << [
  'tika': '1.11',
  'pdfbox': '1.8.10',
  'bouncycastle': '1.52',
  'poi': '3.13'
]

dependencies {
  // mandatory for tika
  compile "org.apache.tika:tika-core:${versions.tika}"
  compile "org.apache.tika:tika-parsers:${versions.tika}"
  compile 'commons-io:commons-io:2.4'
  
  // character set detection
  compile 'com.googlecode.juniversalchardet:juniversalchardet:1.0.3'

  // external parser libraries
  // HTML
  compile 'org.ccil.cowan.tagsoup:tagsoup:1.2.1'
  // Adobe PDF
  compile "org.apache.pdfbox:pdfbox:${versions.pdfbox}"
  compile "org.apache.pdfbox:fontbox:${versions.pdfbox}"
  compile "org.apache.pdfbox:jempbox:${versions.pdfbox}"
  compile "commons-logging:commons-logging:${versions.commonslogging}"
  compile "org.bouncycastle:bcmail-jdk15on:${versions.bouncycastle}"
  compile "org.bouncycastle:bcprov-jdk15on:${versions.bouncycastle}"
  compile "org.bouncycastle:bcpkix-jdk15on:${versions.bouncycastle}"
  // OpenOffice
  compile "org.apache.poi:poi-ooxml:${versions.poi}"
  compile "org.apache.poi:poi:${versions.poi}"
  compile "org.apache.poi:poi-ooxml-schemas:${versions.poi}"
  compile "commons-codec:commons-codec:${versions.commonscodec}"
  compile 'org.apache.xmlbeans:xmlbeans:2.6.0'
  compile 'stax:stax-api:1.0.1'
  // MS Office
  compile "org.apache.poi:poi-scratchpad:${versions.poi}"
  // Apple iWork
  compile 'org.apache.commons:commons-compress:1.10'
}

compileJava.options.compilerArgs << '-Xlint:-cast,-deprecation,-rawtypes'

forbiddenPatterns {
  exclude '**/*.docx'
  exclude '**/*.pdf'
  exclude '**/*.epub'
}

// classes are missing, e.g. org.openxmlformats.schemas.drawingml.x2006.chart.CTExtensionList
thirdPartyAudit.lenient = true
thirdPartyAudit.excludes = [
    // uses internal java api: com.sun.syndication (SyndFeedInput, SyndFeed, SyndEntry, SyndContent)
    'org.apache.tika.parser.feed.FeedParser',
]